Reply with attachment included

Thanks for replying. I don't want to have to use add-in from some third party - demo or paid version. Microsoft outlook should provide the functionality.

Totally agree, Outlook should add this feature in a future update

This will be greatly appreciate if you can add this option. I always have to go back and search for the attachment in the original mail.

Click [Alt] + [F11]

Create new module

Paste code below

Add quick ribbon button for macro

'-------------------------------------------

Sub ReplyAllWithAttachments()
    Dim oReply As Outlook.MailItem
    Dim oItem As Object

    Set oItem = GetCurrentItem()
    If Not oItem Is Nothing Then
        Set oReply = oItem.ReplyAll
        CopyAttachments oItem, oReply
        oReply.Display
        oItem.UnRead = False
    End If

    Set oReply = Nothing
    Set oItem = Nothing
End Sub

Sub CopyAttachments(oSourceItem As Object, oTargetItem As Object)
    Dim oAttachment As Outlook.Attachment
    For Each oAttachment In oSourceItem.Attachments
        If Not oAttachment.FileName Like "image*" Then
            Dim sSavePath As String
            sSavePath = Environ("TEMP") & "" & oAttachment.FileName
            oAttachment.SaveAsFile sSavePath
            oTargetItem.Attachments.Add sSavePath, olByValue, , oAttachment.DisplayName
            Kill sSavePath
        End If
    Next oAttachment
End Sub

Function GetCurrentItem() As Object
    Dim objApp As Outlook.Application
    Set objApp = Application
    On Error Resume Next
    Select Case TypeName(objApp.ActiveWindow)
        Case "Explorer"
            Set GetCurrentItem = objApp.ActiveExplorer.Selection.Item(1)
        Case "Inspector"
            Set GetCurrentItem = objApp.ActiveInspector.CurrentItem
        Case Else
            Set GetCurrentItem = Nothing
    End Select
    On Error GoTo 0
    Set objApp = Nothing
End Function

Hi,

this is of course a great idea and we are using it inside the organization where you are able to share files. If we go outside, we usually do not share and forwarding messages including att.

Plus, sometimes i need to share simple calculation for info; and for that reason i only need to send an att.

robert