Finding the character where two strings do not match

Anonymous
2010-06-11T16:18:02+00:00

I have 2 cells B2 and C2 with strings.

I can tell whether they match or not easily enough.  But I am not sure how to identify the character where the two strings diverge.  Can it be done with a formula (ideas?) or do I need to create a new one (eh?)?

Thanks all. :)

Microsoft 365 and Office | Excel | For home | Windows

Locked Question. This question was migrated from the Microsoft Support Community. You can vote on whether it's helpful, but you can't add comments or replies or follow the question.

0 comments
Answer accepted by question author
Anonymous
2010-06-12T14:02:24+00:00

Nice formula Bernd; however, I would suggest this modification to it so that it can be copied down into blank rows (in anticipation of future entries)...

=IF(AND(B2="",C2=""),"",LOOKUP(2,1/(1=FIND(LEFT(" "&B2,ROW(INDIRECT("1:"&1+LEN(B2))))," "&C2)),ROW(INDIRECT("1:"&1+LEN(B2)))))

I would note for the OP that this formula is entered normally (that is, it is NOT an array-entered formula). And I would also note that the formula is is case-sensitive; the case-insensitive version of it would be this...

=IF(AND(B14="",C14=""),"",LOOKUP(2,1/(1=FIND(LEFT(" "&UPPER(B14),ROW(INDIRECT("1:"&1+LEN(B14))))," "&UPPER(C14))),ROW(INDIRECT("1:"&1+LEN(B14)))))

Was this answer helpful?

3 people found this answer helpful.
0 comments
Answer accepted by question author
Anonymous
2010-06-12T09:25:06+00:00

I have 2 cells B2 and C2 with strings.

I can tell whether they match or not easily enough.  But I am not sure how to identify the character where the two strings diverge.  Can it be done with a formula (ideas?) or do I need to create a new one (eh?)?

Thanks all. :)

Hello,

I suggest to use

=LOOKUP(2,1/(1=FIND(LEFT(" "&B2,ROW(INDIRECT("1:"&1+LEN(B2))))," "&C2)),ROW(INDIRECT("1:"&1+LEN(B2))))

Regards,

Bernd

PS: [Edited on 12-June 11:57 GMT] If VBA is an option you can also use

Function NonMatchPos(s1 As String, s2 As String) As Long

Dim i As Long

i = 1

Do While i <= Len(s1) And i <= Len(s2)

    If Mid(s1, i, 1) <> Mid(s2, i, 1) Then Exit Do

    i = i + 1

Loop

NonMatchPos = i

End Function

www.sulprobil.com

Was this answer helpful?

1 person found this answer helpful.
0 comments

48 additional answers

Sort by: Most helpful
Most helpful Newest Oldest
  1. Anonymous
    2010-06-12T02:11:19+00:00

    Here are the revised test results (the only difference in F2 is sue to case sensitivity):

    aaaaaa aaaaab 6 6 6

    | blah | blax | 4 | 4 | 4 | | apple | bpple | 1 | 1 | 1 | | aaaaaaaaab | aaaaaaaaac | 10 | 10 | 10 | | aaaaaa | aabbab | 3 | 3 | 3 | | a | asdfg | 2 | 2 | 2 | | aaa | a | 2 | 2 | 2 | | Abc | abc | 1 | 4 | 1 | | aBc | aBC | 3 | 4 | 3 | | A | B | 1 | 1 | 1 | | abc | abC | 3 | 4 | 3 | | abc | abc | 4 | 4 | 4 | | aaaab | aaaab | 6 | 6 | 6 |

    F2 is the one mentioned in the above post.

    F1:=LOOKUP(2,1/(1=FIND(LEFT(" "&A1&REPT("|",1+LEN(B1)),ROW(INDIRECT("1:"&2+LEN(A1)))),

    " "&B1&REPT("#",1+LEN(A1)))),ROW(INDIRECT("1:"&2+LEN(A1))))

    F2:=IF(AND(A1="",B1=""),"",MIN(IF(MID(A1,ROW(INDIRECT("1:"&MAX(LEN(A1),LEN(B1)))),1)<>MID(B1,ROW(INDIRECT("1:"&MAX(LEN(A1),LEN(B1)))),1),ROW(INDIRECT("1:"&MAX(LEN(A1),LEN(B1)))),MAX(LEN(A1),LEN(B1))+1)))

    F3:=IFERROR(MATCH(FALSE,EXACT(MID(A1,ROW($1:$10),1),MID(B1,ROW($1:$10),1)),0),LEN(A1)+1)

    And a little trimming got F3 down to:

    F3:=IFERROR(MATCH(0,--EXACT(MID(A1,ROW($1:$10),1),MID(B1,ROW($1:$10),1)),),LEN(A1)+1)

    The last 3 are array entered.

    If this answer solves your problem, please check Mark as Answered. If this answer helps, please click the Vote as Helpful button. Cheers, Shane Devenshire

    Was this answer helpful?

    0 comments
  2. Anonymous
    2010-06-12T01:59:08+00:00

    Actually, I will have those characters in it.

    Was this answer helpful?

    0 comments
  3. Anonymous
    2010-06-12T01:00:49+00:00

    Your testing appears to be using an old formula of mine (your F2 formula) which I replaced earlier because it didn't work correctly. Try using my latest posted formula which I believe works correctly for all situations (can't be absolutely sure, but I am almost absolutely sure). Here is that formula (hopefully correctly) modified to use your A1/B1 cell referencing...

    =IF(AND(A1="",B1=""),"",MIN(IF(MID(A1,ROW(INDIRECT("1:"&MAX(LEN(A1),LEN(B1)))),1)<>MID(B1,ROW(INDIRECT("1:"&MAX(LEN(A1),LEN(B1)))),1),ROW(INDIRECT("1:"&MAX(LEN(A1),LEN(B1)))),MAX(LEN(A1),LEN(B1))+1)))

    Note that this formula also returns the empty string if both A1 and B1 are empty cells.

    Was this answer helpful?

    0 comments