macro to find and replace the case of different characters in a two-column table

Anonymous
2016-06-24T10:32:23+00:00

Hi team,

Currently I am working with this macro

Sub ReplaceFromTableList()

Dim oChanges As Document, oDoc As Document

Dim oTable As Table

Dim oRng As Range

Dim rFindText As Range, rReplacement As Range

Dim i As Long

Dim sFname As String

Dim sAsk As String

    sFname = "C:\Users\Win7\Desktop\macro.docx" 'The table document

    Set oDoc = ActiveDocument

    Set oChanges = Documents.Open(FileName:=sFname, Visible:=False)

    Set oTable = oChanges.Tables(1)

    For i = 1 To oTable.Rows.Count

        Set oRng = oDoc.Range

        Set rFindText = oTable.Cell(i, 1).Range

        rFindText.End = rFindText.End - 1

        Set rReplacement = oTable.Cell(i, 2).Range

        rReplacement.End = rReplacement.End - 1

        With oRng.Find

        .ClearFormatting

        .Replacement.ClearFormatting

        .Execute FindText:=rFindText.Text, _

                 MatchWildcards:=True, _

                 ReplaceWith:=rReplacement.Text, _

                 Replace:=wdReplaceAll

    End With           

    Next i

    oChanges.Close wdDoNotSaveChanges

lbl_Exit:

    Exit Sub

End Sub

This macro finds terms in the first column of a table and replaces them by those on the second column, and it enables you to use wildcards as follows

([Hh])owever \1wv.
<([Aa])s well as> \1wa.

Yet, in some pairs the first character of the first column is not the same as the first one of the second column, as in

expression xprss.

Therefore, I have two questions, namely

a) whether it is possible to use wildcards to somehow carry out an operation which would transmit the upper/lower case of the first character of the first column into the first character of the second column, so that both coincide

b) whether, if such an operation is not possible using wildcards, the macro I am working with (or even a completely different one) could be modified so that my purpose can be succesfully achieved.

I'd very much appreciate any ideas on the alternatives I have.

Microsoft 365 and Office | Word | For home | Windows

Locked Question. This question was migrated from the Microsoft Support Community. You can vote on whether it's helpful, but you can't add comments or replies or follow the question.

0 comments
Answer accepted by question author
Doug Robbins - MVP - Office Apps and Services 323.6K Reputation points MVP Volunteer Moderator
2016-07-03T00:54:16+00:00

In that case, use:

With Sheets(1).Range("A1")

    For i = 0 To .CurrentRegion.Rows.Count

        For k = 0 To 1

            For j = 1 To .Offset(i, k).Characters.Count

                If IsNumeric(Left(.Offset(i, k), 1)) Then

                    GoTo Nextj

                End If

                If Asc(Left(.Offset(i, k), 1)) > 64 And Asc(Left(.Offset(i, k), 1)) < 90 Then

                    GoTo Nextj

                End If

                If Asc(Mid(.Offset(i, k), j, 1)) > 96 And Asc(Mid(.Offset(i, k), j, 1)) < 123 Then

                    .Offset(i, k) = Left(.Offset(i, k), j - 1) & UCase(Mid(.Offset(i, k), j, 1)) & Mid(.Offset(i, k), j + 1)

                    Exit For

                End If

Nextj:

            Next j

        Next k

     Next i

End With

Was this answer helpful?

0 comments
Answer accepted by question author
Paul Edstein 82,871 Reputation points Volunteer Moderator
2016-06-26T02:05:53+00:00

I've made some minor revisions to the previous code, so both macros should now run without error.

Regarding the formatting, unless you use a 4-column table, there's really no reliable way of knowing whether the formats found in the cells are important to the Find/Replace operation. How would one tell, for example, whether the absence of a bold font means the content to be found is not to be bolded, or that bolding is inconsequential? Separate columns to designate the applicability of font attributes for both the Find and the Replace would be required. the following macro envisages such a table, where the presence of content in the 3rd & 4th columns dictate whether the font format is to be taken into account for the Find (column 3) or applied to the Replace (column 4); if the cell has content, the formatting there is applied to the Find and/or Replace, as applicable.

Sub ReplaceFromTableList()

Application.ScreenUpdating = False

Dim Doc As Document, Rng As Range, i As Long, Tbl As Table

Dim sFname As String, StrFnd As String, StrRep As String

sFname = "C:\Users\Win7\Desktop\macro.docx" 'The table document

Set Rng = ActiveDocument.Range

Set Doc = Documents.Open(FileName:=sFname, Visible:=False)

Set Tbl = Doc.Tables(1)

With Rng.Find

  .MatchWildcards = True

  .Wrap = wdFindContinue

  For i = 1 To Tbl.Rows.Count

    .ClearFormatting

    .Replacement.ClearFormatting

    StrFnd = Split(Tbl.Cell(i, 1).Range.Text, vbCr)(0)

    StrRep = Split(Tbl.Cell(i, 2).Range.Text, vbCr)(0)

    .Text = StrFnd

    .Replacement.Text = StrRep

    If Split(Tbl.Cell(i, 3).Range.Text, vbCr)(0) <> "" Then

      Set FntFnd = Tbl.Cell(i, 4).Range.Characters(1).Font

      .Font.Bold = FntFnd.Bold

      .Font.Italic = FntFnd.Italic

      .Font.Underline = FntFnd.Underline

    End If

    If Split(Tbl.Cell(i, 4).Range.Text, vbCr)(0) <> "" Then

      Set FntRep = Tbl.Cell(i, 4).Range.Characters(1).Font

      With .Replacement

        .Font.Bold = FntRep.Bold

        .Font.Italic = FntRep.Italic

        .Font.Underline = FntRep.Underline

      End With

    End If

    .Execute Replace:=wdReplaceAll

    .Text = LCase(StrFnd)

    .Replacement.Text = LCase(StrRep)

    .Execute Replace:=wdReplaceAll

  Next i

End With

Doc.Close wdDoNotSaveChanges

Application.ScreenUpdating = True

End Sub

Was this answer helpful?

0 comments

46 additional answers

Sort by: Oldest
Most helpful Newest Oldest
  1. Paul Edstein 82,871 Reputation points Volunteer Moderator
    2016-06-27T00:09:55+00:00

    Re:

    1. You can add more font attribute tests, such as:

     .Font.Size = FntFnd.Size

     .Font.Name = FntFnd.Name

    but the more of these you add, the more restrictive the macro becomes. If you need that kind of flexibility, you need to take an approach like that described here: http://www.msofficeforums.com/word-vba/29384-vba-word-find-formatted-text-version-only.html#post93796

    1. Not possible for a Find and not possible for a Replace unless you a) copy the content to the clipboard and b) change the Replace expression to '^c'. Furthermore, the LCase conversion wouldn't work.
    2. See 1, above.
    3. See 2, above.

    Was this answer helpful?

    0 comments
  2. Anonymous
    2016-06-29T07:27:00+00:00

    Hi Paul,

    I'll widen my knowledge the following weeks studying the last link you’ve provided, but now I need to start working with your last macro.

    Therefore, as the macro requires LCase conversion, but my spreadsheets are written in lowercase, now I need to know how I can automate the process of turning the first character (once again, excluding wildcards) of both columns into uppercase.

    If this last question has to be in a new post, please just let me now.

    Was this answer helpful?

    0 comments
  3. Paul Edstein 82,871 Reputation points Volunteer Moderator
    2016-06-29T19:23:59+00:00

    My impression was that, so far, we'd been discussing a Word table, not a worksheet, and the Word tables had the first character in upper case. Simply copying the table to an Excel worksheet wouldn't change anything to lower case, so I don't understand what you mean by "my spreadsheets are written in lowercase".

    The macro in the link has:

          .Text = Split(xlFExpr, "|")(i)

          .Replacement.Text = Split(xlRExpr, "|")(i)

          .Execute Replace:=wdReplaceAll

    To do the same kind of lower-case processing the previous macros I provided do, simply follow those lines with:

          .Text = LCase(Split(xlFExpr, "|")(i))

          .Replacement.Text = LCase(Split(xlRExpr, "|")(i))

          .Execute Replace:=wdReplaceAll

    Was this answer helpful?

    0 comments