Userforms and VBA in Word 2007/2010 - Combobox with addresses

Anonymous
2012-02-09T23:44:33+00:00

Hello,

I've been trying to get used to working with User forms, and I've gone as far as being able to create a form, but I am uncertain how to code it to work with a template.  I'm still waiting for some books to come in that I ordered to help me out, so in the mean time I'm looking for a little assistance from you amazing people :-)

The main thing I'm trying to work on is creating a combobox so that I can have a very long list that will continue to grow as I obtain more contacts.  I wanted to use dropdown form fields but realize I can't exceed 25 items per dropdown field.  I could use several dropdown fields to call the data from another document, but I'd like things to look clean.  So I think a combobox will be a much better option.  I want the combo box to have the names of all my contacts, and once a contact is selected, I want their entire mailing address to appear at the top of my letter template.

So let's say I select 'Option1' in the combo box, I'd like the top of my letter to show something resembling the following:

Recipient Name

Address

City, State/Province

Zip Code/Postal Code

I hope I've explained what I'd like done clearly enough, but if you require further explanation I'd be happy to provide.  If there's a better way to do this I'd be happy to hear it.

Thank you!

Microsoft 365 and Office | Word | For home | Windows

Locked Question. This question was migrated from the Microsoft Support Community. You can vote on whether it's helpful, but you can't add comments or replies or follow the question.

0 comments
Answer accepted by question author
Anonymous
2012-02-10T07:04:41+00:00

The simplest solution, if you have it, is to use Outlook to both store the addresses and provide an address book dialog to insert the addresses where you require them. This is covered at http://www.gmayor.com/Macrobutton.htm.

If you want to list the addresses on a userform you will need a multi-column list box and somewhere to store the addresses - probably a document containing a table or perhaps an Excel worksheet, which can be read into the list box. Take a look at http://gregmaxey.mvps.org/word_tip_pages/Old_Tip_Pages/Populate_UserForm_ListBox.htm.

You can then populate a document variable with the contents of the selected item and use a docvariable field to reproduce the value from the docvariable in the document.

Was this answer helpful?

1 person found this answer helpful.
0 comments
Answer accepted by question author
Anonymous
2012-02-16T08:44:29+00:00

Don't use bookmarks with a protected form, use a docvariable field in the document and write the value of the selected item from the list box to the variable. Then the protection becomes irrelevant.

If using a multi-column list box, then you will need to re compile the address from the list box columns in the format you require into the variable. Something like the following. I have set the listbox to display only the first column to avoid clutter.

Insert { DocVariable Address } into the document at the place you want the address to appear.

Option Explicit

Private oVars As Variables

Private oSource As Document

Private oTable As Table

Private oRng As Range

Private strWidth As String

Private i As Long, j As Long, k As Long

Private m As Long, n As Long

Private Sub UserForm_Initialize()

Set oSource = Documents.Open(FileName:="C:\Addresses.doc", _

                             AddToRecentFiles:=False, _

                             Visible:=False)

Set oTable = oSource.Tables(1)

'Get the number of list members (i.e., table rows - 1 if header row is used)

i = oTable.Rows.Count - 1

'Get the number of list member attributes (i.e., table columns)

j = oTable.Columns.Count

'Set the number of columns in the Listbox

With Me.ListBox1

    .ColumnCount = j

    strWidth = .Width - 2

    For k = 2 To j

        strWidth = strWidth & ";" & 0

    Next k

    .ColumnWidths = strWidth

    'Load list members into an array

    ReDim myArray(i, j)

    For n = 0 To j - 1

        For m = 0 To i - 1

            Set oRng = oTable.Cell(m + 2, n + 1).Range

            oRng.End = oRng.End - 1

            myArray(m, n) = oRng.Text

        Next m

    Next n

    'Populate the ListBox using the array

    .list() = myArray

    .ListIndex = 0

End With

'Close the source file

oSource.Close SaveChanges:=wdDoNotSaveChanges

End Sub

Private Sub CommandButton1_Click()

Set oVars = ActiveDocument.Variables

oVars("Address").Value = Me.ListBox1.Column(0) & vbCr & _

                         Me.ListBox1.Column(1) & vbCr & _

                         Me.ListBox1.Column(2) & vbCr & _

                         Me.ListBox1.Column(3)

ActiveDocument.Fields.Update

Unload Me

End Sub

Was this answer helpful?

0 comments

42 additional answers

Sort by: Oldest
Most helpful Newest Oldest
  1. Anonymous
    2012-02-17T09:36:20+00:00

    Option Explicit

    Private oVars As Variables

    Private oSource1 As Document, oSource2 As Document

    Private oTable As Table

    Private oRng As Range

    Private strWidth As String

    Private i As Long, j As Long, k As Long

    Private m As Long, n As Long

    Private Sub CommandButton1_Click()

    Set oVars = ActiveDocument.Variables

    oVars("Address").Value = Me.ListBox1.Column(0) & vbCr & _

                             Me.ListBox1.Column(1) & vbCr & _

                             Me.ListBox1.Column(2) & vbCr & _

                             Me.ListBox1.Column(3)

    oVars("Doctemplate").Value = Me.ListBox2.Column(1)

    ActiveDocument.Fields.Update

    Unload Me

    End Sub

    Private Sub UserForm_Initialize()

    Set oSource1 = Documents.Open(FileName:="C:\Addresses.doc", _

                                 AddToRecentFiles:=False, _

                                 Visible:=False)

    Set oSource2 = Documents.Open(FileName:="C:\Documents.doc", _

                                 AddToRecentFiles:=False, _

                                 Visible:=False)

    Set oTable = oSource1.Tables(1)

    'Get the number of list members (i.e., table rows - 1 if header row is used)

    i = oTable.Rows.Count - 1

    'Get the number of list member attributes (i.e., table columns)

    j = oTable.Columns.Count

    'Set the number of columns in the Listbox

    With Me.ListBox1

        .ColumnCount = j

        strWidth = .Width - 2

        For k = 2 To j

            strWidth = strWidth & ";" & 0

        Next k

        .ColumnWidths = strWidth

        'Load list members into an array

        ReDim myArray(i, j)

        For n = 0 To j - 1

            For m = 0 To i - 1

                Set oRng = oTable.Cell(m + 2, n + 1).Range

                oRng.End = oRng.End - 1

                myArray(m, n) = oRng.Text

            Next m

        Next n

        'Populate the ListBox using the array

        .list() = myArray

        .ListIndex = 0

    End With

    Set oTable = oSource2.Tables(1)

    'Get the number of list members (i.e., table rows - 1 if header row is used)

    i = oTable.Rows.Count - 1

    'Get the number of list member attributes (i.e., table columns)

    j = oTable.Columns.Count

    'Set the number of columns in the Listbox

    With Me.ListBox2

        .ColumnCount = j

        strWidth = .Width - 2

        For k = 2 To j

            strWidth = strWidth & ";" & 0

        Next k

        .ColumnWidths = strWidth

        'Load list members into an array

        ReDim myArray(i, j)

        For n = 0 To j - 1

            For m = 0 To i - 1

                Set oRng = oTable.Cell(m + 2, n + 1).Range

                oRng.End = oRng.End - 1

                myArray(m, n) = oRng.Text

            Next m

        Next n

        'Populate the ListBox using the array

        .list() = myArray

        .ListIndex = 0

    End With

    'Close the source file

    oSource1.Close SaveChanges:=wdDoNotSaveChanges

    oSource2.Close SaveChanges:=wdDoNotSaveChanges

    End Sub

    Was this answer helpful?

    0 comments
  2. Anonymous
    2012-02-17T14:51:40+00:00

    You make it look so easy...

    Thanks again!!  I think I'm starting to understand how this stuff works with the more questions I ask.  You're awesome!

    Was this answer helpful?

    0 comments
  3. Charles Kenyon 171.2K Reputation points Volunteer Moderator
    2012-02-17T17:39:38+00:00

    You make it look so easy...

     

    Thanks again!!  I think I'm starting to understand how this stuff works with the more questions I ask.  You're awesome!

    Just wanted to urge you to continue asking questions. Not only do you learn but so do the rest of us! You have been working with two of the masters out there.

    Was this answer helpful?

    0 comments