Userforms and VBA in Word 2007/2010 - Combobox with addresses

Anonymous

Hello,

I've been trying to get used to working with User forms, and I've gone as far as being able to create a form, but I am uncertain how to code it to work with a template. I'm still waiting for some books to come in that I ordered to help me out, so in the mean time I'm looking for a little assistance from you amazing people :-)

The main thing I'm trying to work on is creating a combobox so that I can have a very long list that will continue to grow as I obtain more contacts. I wanted to use dropdown form fields but realize I can't exceed 25 items per dropdown field. I could use several dropdown fields to call the data from another document, but I'd like things to look clean. So I think a combobox will be a much better option. I want the combo box to have the names of all my contacts, and once a contact is selected, I want their entire mailing address to appear at the top of my letter template.

So let's say I select 'Option1' in the combo box, I'd like the top of my letter to show something resembling the following:

Recipient Name

Address

City, State/Province

Zip Code/Postal Code

I hope I've explained what I'd like done clearly enough, but if you require further explanation I'd be happy to provide. If there's a better way to do this I'd be happy to hear it.

Thank you!

Locked Question. This question was migrated from the Microsoft Support Community. You can vote on whether it's helpful, but you can't add comments or replies or follow the question.

0 comments

Answer accepted by question author

Anonymous

The simplest solution, if you have it, is to use Outlook to both store the addresses and provide an address book dialog to insert the addresses where you require them. This is covered at http://www.gmayor.com/Macrobutton.htm.

If you want to list the addresses on a userform you will need a multi-column list box and somewhere to store the addresses - probably a document containing a table or perhaps an Excel worksheet, which can be read into the list box. Take a look at http://gregmaxey.mvps.org/word_tip_pages/Old_Tip_Pages/Populate_UserForm_ListBox.htm.

You can then populate a document variable with the contents of the selected item and use a docvariable field to reproduce the value from the docvariable in the document.

0 comments

Answer accepted by question author

Anonymous

Don't use bookmarks with a protected form, use a docvariable field in the document and write the value of the selected item from the list box to the variable. Then the protection becomes irrelevant.

If using a multi-column list box, then you will need to re compile the address from the list box columns in the format you require into the variable. Something like the following. I have set the listbox to display only the first column to avoid clutter.

Insert { DocVariable Address } into the document at the place you want the address to appear.

Option Explicit

Private oVars As Variables

Private oSource As Document

Private oTable As Table

Private oRng As Range

Private strWidth As String

Private i As Long, j As Long, k As Long

Private m As Long, n As Long

Private Sub UserForm_Initialize()

Set oSource = Documents.Open(FileName:="C:\Addresses.doc", _

AddToRecentFiles:=False, _

Visible:=False)

Set oTable = oSource.Tables(1)

'Get the number of list members (i.e., table rows - 1 if header row is used)

i = oTable.Rows.Count - 1

'Get the number of list member attributes (i.e., table columns)

j = oTable.Columns.Count

'Set the number of columns in the Listbox

With Me.ListBox1

.ColumnCount = j

strWidth = .Width - 2

For k = 2 To j

strWidth = strWidth & ";" & 0

Next k

.ColumnWidths = strWidth

'Load list members into an array

ReDim myArray(i, j)

For n = 0 To j - 1

For m = 0 To i - 1

Set oRng = oTable.Cell(m + 2, n + 1).Range

oRng.End = oRng.End - 1

myArray(m, n) = oRng.Text

Next m

Next n

'Populate the ListBox using the array

.list() = myArray

.ListIndex = 0

End With

'Close the source file

oSource.Close SaveChanges:=wdDoNotSaveChanges

End Sub

Private Sub CommandButton1_Click()

Set oVars = ActiveDocument.Variables

oVars("Address").Value = Me.ListBox1.Column(0) & vbCr & _

Me.ListBox1.Column(1) & vbCr & _

Me.ListBox1.Column(2) & vbCr & _

Me.ListBox1.Column(3)

ActiveDocument.Fields.Update

Unload Me

End Sub

0 comments

42 additional answers

Anonymous

2012-03-12T14:37:00+00:00

Interesting mix of bookmarks and variables, but the following should work. You can use http://www.gmayor.com/BookmarkandVariableEditor.htm to see exactly what is inserted into the variables and bookmarks.

It is not clear what ListBox 2 is doing and you appear to be using a mix of document and excel data sources rather than one or the other, for no obvious reason, but it should work.

Option Explicit

Private oVars As Variables

Private oSource1 As Document

Private oTable As Table

Private oRng As Range

Private strWidth As String

Private sVar As String

Private i As Long, j As Long, k As Long

Private m As Long, n As Long

Private Sub CmdBtnCancel_Click()

    Unload Me

End Sub

Private Sub CommandButton1_Click()

With ActiveDocument

    .Variables("Salutation").Value = Me.TextBox1.Text

    .Variables("Attention").Value = Me.TextBox2.Text

    .Variables("SentBy").Value = Me.TextBox3.Text

    .Variables("Period").Value = Me.TextBox4.Text

    .Variables("FileUnder").Value = Me.TextBox5.Text

    .Variables("Amount").Value = Me.TextBox6.Text

    .Fields.Update

End With

Set oVars = ActiveDocument.Variables

oVars("Address").Value = Me.ListBox1.Column(1) & vbCr & _

                         Me.ListBox1.Column(2) & vbCr & _

                         Me.ListBox1.Column(3) & vbCr & _

                         Me.ListBox1.Column(4)

For i = 0 To Me.ListBox2.ColumnCount - 1

    sVar = str(i + 1)

    oVars(sVar).Value = Me.ListBox2.Column(i)

Next i

WriteTextToBM "Closing", Me.ListBox3.Column(1)

WriteTextToBM "Name", Me.ListBox3.Column(0)

WriteTextToBM "Position", Me.ListBox3.Column(3)

InsertBBInBM "SigImage", Me.ListBox3.Column(2)

ActiveDocument.Fields.Update

Unload Me

End Sub

Private Sub Userform_Initialize()

Dim xlApp As Object

Dim xlWB As Object

Dim xlWS As Object

Dim cRows As Long

Dim cCols As Long

Dim i As Long

Dim j As Long

Dim k As Long

Dim strWidth As String

Set xlApp = CreateObject("Excel.Application")

Set xlWB = xlApp.Workbooks.Open("C:\Templates\TemplateDocs\ClientIntake.xlsx")

Set xlWS = xlWB.Worksheets(1)

Set oSource1 = Documents.Open(FileName:="C:\Templates\TemplateDocs\Addresses.doc", _

                              AddToRecentFiles:=False, _

                              Visible:=False)Set oTable = oSource1.Tables(1)

'Get the number of list members (i.e., table rows - 1 if header row is used)

i = oTable.Rows.Count - 1

'Get the number of list member attributes (i.e., table columns)

j = oTable.Columns.Count

'Set the number of columns in the Listbox

With Me.ListBox1

      .ColumnCount = j

     strWidth = .Width - 2

     For k = 2 To j

         strWidth = strWidth & ";" & 0

     Next k

     .ColumnWidths = strWidth

     'Load list members into an array

     ReDim myarray(i, j)

     For n = 0 To j - 1

         For m = 0 To i - 1

             Set oRng = oTable.Cell(m + 2, n + 1).Range

             oRng.End = oRng.End - 1

             myarray(m, n) = oRng.Text

         Next m

     Next n

     'Populate the ListBox using the array

     .list() = myarray

     .ListIndex = 0

End With

oSource1.Close SaveChanges:=wdDoNotSaveChanges

ListBox2.ColumnCount = cCols

With Me.ListBox2

cRows = xlWS.Range("A1").CurrentRegion.Rows.Count

cCols = xlWS.Range("A1").CurrentRegion.Columns.Count

    .ColumnCount = cCols

    strWidth = .Width - 2

    For k = 2 To cCols

        strWidth = strWidth & ";" & 0

    Next k

    .ColumnWidths = strWidth

    For i = 2 To cRows

        .AddItem xlWS.Cells(i, 1)

        For j = 1 To cCols

            .list(.ListCount - 1, j) = xlWS.Cells(i, j + 1)

        Next j

    Next i

End With

Set xlWS = Nothing

Set xlWB = Nothing

xlApp.Quit

Set xlApp = Nothing

With Me.ListBox3

   .ColumnCount = 4

   .ColumnWidths = "150;0;0;0"

   .AddItem "NAME1"

   .list(0, 1) = "Yours truly,"

   .list(0, 2) = "bbNAME1"

   .list(0, 3) = "Job Title"

   .AddItem "NAME2"

   .list(1, 1) = "Yours truly,"

   .list(1, 2) = "bbNAME2"

   .list(1, 3) = "Job Title"

   .AddItem "NAME3"

   .list(2, 1) = "Yours truly,"

   .list(2, 2) = "bbNAME3"

   .list(2, 3) = "Job Title"

   .AddItem "NAME4"

   .list(3, 1) = "Yours truly,"

   .list(3, 2) = "bbNAME4"

   .list(3, 3) = "Job Title"

   .AddItem "NAME5"

   .list(4, 1) = "Yours truly,"

   .list(4, 2) = "bbNAME5"

   .list(4, 3) = "Job Title"

End With

End Sub
Was this answer helpful?

0 comments No comments
Anonymous

2012-03-13T13:43:37+00:00

I tried this yesterday and received yet another error. I think I'll end up using Excel as opposed to Word for my data sources, so I might just start my userform from scratch and get back to you when I've re-compiled everything you've provided to me in past. I have a few new ideas I'd like to use in the form to make it less cluttered. Being new to this stuff is both fun and frustrating lol...

Anyway, thanks again for your help. The above probably does work and there may just be something wrong that I'll figure out when I go back and start again.
Was this answer helpful?

0 comments No comments
Anonymous

2012-04-05T22:58:41+00:00

I'm determined to get this thing working now. Been trying for a few weeks to no avail... Considering your suggestions have worked for you, then there has to be something I'm not seeing. Is it possible there's an object library that I don't have that you do? Is there one I should download from somewhere?
Was this answer helpful?

0 comments No comments