Userforms and VBA in Word 2007/2010 - Combobox with addresses

Graham,

I believe your suggestion will likely work, I'm still very new to this and it takes me a while to learn anything lol...

Here is my code so far:

Option Explicit

Private Sub UserForm_Initialize()

Dim myArray() As Variant

Dim sourcedoc As Document

Dim i As Integer

Dim j As Integer

Dim myitem As Range

Dim m As Long

Dim n As Long

Application.ScreenUpdating = False

'Modify the following line to point to your list member file and open the document

Set sourcedoc = Documents.Open(FileName:="C:\Addresses.doc")

'Get the number of list members (i.e., table rows - 1 if header row is used)

i = sourcedoc.Tables(1).Rows.Count - 1

'Get the number of list member attributes (i.e., table columns)

j = sourcedoc.Tables(1).Columns.Count

'Set the number of columns in the Listbox

ListBox1.ColumnCount = j

'Load list members into an array

ReDim myArray(i, j)

For n = 0 To j - 1

  For m = 0 To i - 1

    Set myitem = sourcedoc.Tables(1).Cell(m + 2, n + 1).Range

    myitem.End = myitem.End - 1

    myArray(m, n) = myitem.Text

  Next m

Next n

'Populate the ListBox using the array

ListBox1.List() = myArray

'Close the source file

sourcedoc.Close SaveChanges:=wdDoNotSaveChanges

End Sub

Private Sub CommandButton1_Click()

Dim i As Integer

Dim Address As String

Dim oRng As Word.Range

Address = ""

For i = 1 To ListBox1.ColumnCount

  ListBox1.BoundColumn = 1

  If i < ListBox1.ColumnCount Then

    Address = Address & ListBox1.Value & vbCr

  Else

    Address = Address & ListBox1.Value & vbCr

  End If

Next i

Set oRng = ActiveDocument.Bookmarks("Address").Range

oRng.Text = Address

ActiveDocument.Bookmarks.Add "Address", oRng

Me.Hide

End Sub

I can get the listbox to call the table I have created with all the addresses I'd like to use in my template, but I can't seem to get it to properly display without an error.  I'd also like it to display in the template as the following format:

Name

Address

City, State/Province

Zip/Postal Code

So my table looks like the below:

Column1                  Column2                  Column3                  Column4                  

Test1                         Address                   City, State/Prov        Zip/Postal Code

Test2                         Address                   City, State/Prov        Zip/Postal Code

Test3                         Address                   City, State/Prov        Zip/Postal Code

Test4                         Address                   City, State/Prov        Zip/Postal Code

So let's say I click the command button after selecting the row containing Test1, it returns this:

Test1

Test1

Test1

Test1

Is there something in my code that needs to be fixed to return this?:

Test1

Address

City, State/Prov

Zip/Postal Code

Also, this is why I was asking for an unprotect and re-protect method because the example on the webpage you suggested says to insert with bookmarks and I am asked to debug if the form is protected when clicking the command button.

Thanks!

If you assign the value from the userform field to a docvariable and use a docvariable field to display the result rather than a form field, then there is no need to unprotect the form. The field will update to display the data e.g.

Dim oVars As Variables

Dim oFld As Field

Set oVars = ActiveDocument.Variables

oVars("VariableName").Value = "This is the value you want to display"

For Each oFld In ActiveDocument.Fields

    If oFld.Type = wdFieldDocVariable Then oFld.Update

Next oFld

I don't have time to parse it right now. What follows is from a module to unprotect a protected form that has a password stored in a document variable, make changes, and reprotect it.

Option Explicit

Public sPass As String

' Module and Project Written by Charles Kyle Kenyon

' May 2001, Copyright 2001 All rights reserved

Sub DucesTecum()

'

' DucesTecum Macro

' OnExit macro for DucesTecum Checkbox

' "&chr(10)&"Macro recorded 05/16/2001 by Charles Kyle Kenyon

'

    Dim strBringWith As String, rRange As Range

    With ActiveDocument

        UnProtectSubpoena  'subroutine below

        Set rRange = .Bookmarks("YouBringYes").Range

        'Save result of form field

        strBringWith = .FormFields("BringWhat").Result

        If .FormFields("chkDucesTecum").CheckBox.Value _

            = True Then

            .FormFields("DucesTecumTitle").TextInput.EditType _

                Type:=wdRegularText, Default:=" Duces Tecum "

            If strBringWith = "" Then strBringWith = _

                "Bring what?" 'End If

            .FormFields("BringWhat").TextInput.EditType _

                Type:=wdRegularText, Default:=strBringWith, _

                    Enabled:=True

            rRange.Font.DoubleStrikeThrough = False

            rRange.Font.Bold = True

            .FormFields("BringWhat").Select

        Else

            .FormFields("DucesTecumTitle").TextInput.EditType _

                Type:=wdRegularText, Default:=" ", Enabled:=False

            .FormFields("BringWhat").TextInput.EditType _

                Type:=wdRegularText, Default:="", Enabled:=False

            rRange.Font.DoubleStrikeThrough = True

            rRange.Font.Bold = False

            .FormFields("chkThirdParty").Select

        End If

        .Protect wdAllowOnlyFormFields, True, sPass

    End With

End Sub

Sub ThirdParty()

'

' ThirdParty Macro

' OnExit Macro for Third-Party Checkbox

' "&chr(10)&"Macro written 05/16/2001 by Charles Kyle Kenyon

'

    Dim rRange As Range

    With ActiveDocument

        UnProtectSubpoena 'subroutine below

        Set rRange = .Bookmarks("ThirdPartyLanguage").Range

        rRange.Font.DoubleStrikeThrough = _

            Not .FormFields("chkThirdParty").CheckBox.Value

        rRange.Font.Bold = _

            .FormFields("chkThirdParty").CheckBox.Value

        .Protect wdAllowOnlyFormFields, True, sPass

    End With

End Sub

Private Sub UnProtectSubpoena() 'Subroutine for other procedures

    With ActiveDocument

        sPass = .Variables("FormPassWord")

        If .ProtectionType <> wdNoProtection Then .Unprotect (sPass)

        ' End If

    End With

End Sub

---

End of module. Hope this is useful to you.