How to create restore point in windows 7

Anonymous
2010-01-10T14:30:17+00:00
  • I just bought a new computer that's running windows 7. My previous computer had XP. I would open system restore  create my own restore points periodically. Is there a way to do that in windows 7. When i open system restore, the only option I get is restore to an earlier date. Not create a restore point.
Windows for home | Previous Windows versions | Recovery and backup

Locked Question. This question was migrated from the Microsoft Support Community. You can vote on whether it's helpful, but you can't add comments or replies or follow the question.

0 comments
Answer accepted by question author
Anonymous
2011-07-26T12:31:26+00:00

To create a restore point for windows 7 Start / Control Panel / System / System Protection / At bottom of screen last button on right says create. Click it and it will ask you to create a restore point discription for the restore. hope this helps you.

Was this answer helpful?

200+ people found this answer helpful.
0 comments
Answer accepted by question author
Anonymous
2010-01-10T22:12:05+00:00

Under WinXP the creation of restore points and the restore function itself were in the same place. Under Windows 7 you have a couple of methods:

  • Control Panel / System / System protection
  • Through the script below.

To do it with a script, save the code below as ManualRestorePoint.vbs, then double-click it.

'------------------------------------------------------

'Create an instant System Restore Point under Windows 7

'------------------------------------------------------

If WScript.Arguments.Count = 0 Then

  Set oShell = CreateObject("Shell.Application")

  oShell.ShellExecute "wscript.exe", """" _

  & WScript.ScriptFullName & """ Run", , "runas", 1

Else

  Set oWshShell = WScript.CreateObject("WScript.Shell")

  oWshShell.Popup "Creating a SystemRestore point. Please wait.", _

    2, "System Restore", 0

  swinmgmts = "winmgmts:\.\root\default:Systemrestore"

  GetObject(swinmgmts).CreateRestorePoint _

    "Manual Restore Point", 0, 100

  MsgBox "System Restore Point created", 0, "System Restore"

End If

_________________________

If this was helpful, please vote by clicking the green triangle. If it solves the issue, click "Propose as Answer". Thanks.

Was this answer helpful?

10+ people found this answer helpful.
0 comments

64 additional answers

Sort by: Oldest
Most helpful Newest Oldest
  1. Anonymous
    2013-03-31T17:07:59+00:00

     '----------------------------------------------------

    'Create a manual System Restore Point under Windows 7

    '6 Jan 2012 FNL

    '----------------------------------------------------

    If WScript.Arguments.Count = 0 Then

      Set oShell = CreateObject("Shell.Application")

      oShell.ShellExecute "wscript.exe", """" & WScript.ScriptFullName & """ Run", , "runas", 1

    Else

      sDescription = InputBox("Name of Restore Point", "System Restore", "Manual Restore Point")

      if ltrim(sDescription) = "" then WScript.Quit

      Set oWshShell = WScript.CreateObject("WScript.Shell")

      Set oFSO = CreateObject("Scripting.FileSystemObject")

      Popup True

      sWinmgmts = "winmgmts:\.\root\default:Systemrestore"

      GetObject(sWinmgmts).CreateRestorePoint sDescription, 0, 100

      Popup False

    End If

    '-----------------------------

    'Create or kill a pop-up panel

    '-----------------------------

    Sub Popup(bCreate)

      sTempScript = oWshShell.ExpandEnvironmentStrings("%temp%\SRTemp.vbs")

      If bCreate Then

        Set oTempscript = oFSO.CreateTextFile(sTempScript, True)

        oTempscript.WriteLine "MsgBox ""Creating a System Restore Point."" & vbLF & " _

            & """Please wait until the action is complete."", 64, ""System Restore"""

        oTempscript.Close

        oWshShell.Run "wscript.exe """ & sTempScript & """", 0, False

      Else

        Set cProcessList = GetObject("winmgmts:\.\root\cimv2").ExecQuery _

          ("Select * from Win32_Process Where Name = 'wscript.exe'")

        If cProcessList.Count > 0 Then    'Kill the pop-up dialog box

          For Each oProcess In cProcessList

             If InStr(1, oProcess.CommandLine, sTempScript, 1) > 0 Then oProcess.Terminate

          Next

            oFSO.DeleteFile sTempScript

        End If

        MsgBox "The System Restore Point """ & sDescription & """ was created.", 0, "System Restore"

      End If

    End Sub  

    This worked for me to create a system restore but how do you create it and make it to configure it to use Current Usage and set it at 5%.

    I have Created a Windows 7 Home Premium , install.wim file and on install as a fresh install with updates it turns off and sets the Max Usage at 0% and I would like to set it at 5% since I work in a computer repair shop and some people come in for reinstalls and I only have it created for Windows 7 Home Premium x86.

    If you have a vbs script that will allow me to edit on install, that would be great.

    Thanks, Daniel.

    Was this answer helpful?

    0 comments
  2. Anonymous
    2013-05-09T02:52:27+00:00

    Thanks Dude! It's Good And Work. And it is better solution then other.

    Keep It up man.

    Thanks For Helping.

    Was this answer helpful?

    0 comments
  3. Anonymous
    2013-08-05T21:08:28+00:00

    I tried this solution and it dates it with the current date. I need to have a way to have the restore point a few days in the past. Any idea's

    Was this answer helpful?

    0 comments