How to create restore point in windows 7

Anonymous
2010-01-10T14:30:17+00:00
  • I just bought a new computer that's running windows 7. My previous computer had XP. I would open system restore  create my own restore points periodically. Is there a way to do that in windows 7. When i open system restore, the only option I get is restore to an earlier date. Not create a restore point.
Windows for home | Previous Windows versions | Recovery and backup

Locked Question. This question was migrated from the Microsoft Support Community. You can vote on whether it's helpful, but you can't add comments or replies or follow the question.

0 comments
Answer accepted by question author
Anonymous
2011-07-26T12:31:26+00:00

To create a restore point for windows 7 Start / Control Panel / System / System Protection / At bottom of screen last button on right says create. Click it and it will ask you to create a restore point discription for the restore. hope this helps you.

Was this answer helpful?

200+ people found this answer helpful.
0 comments
Answer accepted by question author
Anonymous
2010-01-10T22:12:05+00:00

Under WinXP the creation of restore points and the restore function itself were in the same place. Under Windows 7 you have a couple of methods:

  • Control Panel / System / System protection
  • Through the script below.

To do it with a script, save the code below as ManualRestorePoint.vbs, then double-click it.

'------------------------------------------------------

'Create an instant System Restore Point under Windows 7

'------------------------------------------------------

If WScript.Arguments.Count = 0 Then

  Set oShell = CreateObject("Shell.Application")

  oShell.ShellExecute "wscript.exe", """" _

  & WScript.ScriptFullName & """ Run", , "runas", 1

Else

  Set oWshShell = WScript.CreateObject("WScript.Shell")

  oWshShell.Popup "Creating a SystemRestore point. Please wait.", _

    2, "System Restore", 0

  swinmgmts = "winmgmts:\.\root\default:Systemrestore"

  GetObject(swinmgmts).CreateRestorePoint _

    "Manual Restore Point", 0, 100

  MsgBox "System Restore Point created", 0, "System Restore"

End If

_________________________

If this was helpful, please vote by clicking the green triangle. If it solves the issue, click "Propose as Answer". Thanks.

Was this answer helpful?

10+ people found this answer helpful.
0 comments

64 additional answers

Sort by: Newest
Most helpful Newest Oldest
  1. Anonymous
    2012-01-06T22:13:12+00:00

    FYI, if you click "Cancel" the script throws a script  error and shuts down.  It doesn't create a Restore Point, though, so it's not a problem for me.  When I don't cancel, it does its job just fine.

    A bit of sloppy programming on my side - thanks for pointing this out. I have since edited the code I posted previously. Please use the modified version.

    Was this answer helpful?

    0 comments
  2. Anonymous
    2012-01-06T21:57:21+00:00

    Thank you so much.  Your script works fine. 

    FYI, if you click "Cancel" the script throws a script  error and shuts down.  It doesn't create a Restore Point, though, so it's not a problem for me.  When I don't cancel, it does its job just fine.

    Yes, I should have started a new thread, but I didn't even notice the dates.  Next time, thanks!

    Airpilot.

    Was this answer helpful?

    0 comments
  3. Anonymous
    2012-01-06T11:48:52+00:00

    Script works fine for me, thanks.  A question - can the script be modified to allow me to name the Restore Point, using the same pop-up window I see when I use Win 7 HP Start / Control Panel / System / System Protection / ?  Or, can the script be modified to include a name I've added to the script every time I run the script?

    Thanks,

    Airpilot

    You can use this modified version of the script. It prompts you for a description of the restore point.

    Note also that this thread is now two years old and marked as answered. You're lucky that I happened to spot your query. The recommended method is to start your own thread and refer to pre-existing threads if necessary.

    '----------------------------------------------------

    'Create a manual System Restore Point under Windows 7

    '6 Jan 2012 FNL

    '----------------------------------------------------

    If WScript.Arguments.Count = 0 Then

      Set oShell = CreateObject("Shell.Application")

      oShell.ShellExecute "wscript.exe", """" & WScript.ScriptFullName & """ Run", , "runas", 1

    Else

      sDescription = InputBox("Name of Restore Point", "System Restore", "Manual Restore Point")

      if ltrim(sDescription) = "" then WScript.Quit

      Set oWshShell = WScript.CreateObject("WScript.Shell")

      Set oFSO = CreateObject("Scripting.FileSystemObject")

      Popup True

      sWinmgmts = "winmgmts:\.\root\default:Systemrestore"

      GetObject(sWinmgmts).CreateRestorePoint sDescription, 0, 100

      Popup False

    End If

    '-----------------------------

    'Create or kill a pop-up panel

    '-----------------------------

    Sub Popup(bCreate)

      sTempScript = oWshShell.ExpandEnvironmentStrings("%temp%\SRTemp.vbs")

      If bCreate Then

        Set oTempscript = oFSO.CreateTextFile(sTempScript, True)

        oTempscript.WriteLine "MsgBox ""Creating a System Restore Point."" & vbLF & " _

            & """Please wait until the action is complete."", 64, ""System Restore"""

        oTempscript.Close

        oWshShell.Run "wscript.exe """ & sTempScript & """", 0, False

      Else

        Set cProcessList = GetObject("winmgmts:\.\root\cimv2").ExecQuery _

          ("Select * from Win32_Process Where Name = 'wscript.exe'")

        If cProcessList.Count > 0 Then    'Kill the pop-up dialog box

          For Each oProcess In cProcessList

             If InStr(1, oProcess.CommandLine, sTempScript, 1) > 0 Then oProcess.Terminate

          Next

            oFSO.DeleteFile sTempScript

        End If

        MsgBox "The System Restore Point """ & sDescription & """ was created.", 0, "System Restore"

      End If

    End Sub

    Was this answer helpful?

    0 comments